package 
{
	import flash.display.MovieClip;
	import flash.events.KeyboardEvent;
 
	/********************************************************************
	* Description : This is the main document Class file.
	* @author Alex T.
	 ********************************************************************/
	public class  Main extends MovieClip
	{
		public var mcCursor:MovieClip;
		public var MCCURSOR_X:int = 150;
		public var MCCURSOR_Y:int = 150;
 
		public function Main( ) {
			resetCursorPosition();
			// Attaching stage keyListeners to listen to keyboard input 
			stage.addEventListener(KeyboardEvent.KEY_DOWN, handleKeyDown );
		}
 
		private function handleKeyDown( event:KeyboardEvent ):void {
			// This is where we handle what to do when there's an input
                        // event.keyCode returns a keyCode of the particular keyboard key.
			// trace( "KeyCode received : " + event.keyCode ) ;
			switch (event.keyCode) {
				case 32:
					      // Spacebar is pressed. Enables recentering.
					      resetCursorPosition();
				break;
 
				case 37:
					      // key left
                                              mcCursor.x = mcCursor.x - 2;
				break;
 
				case 38:
					      // key up   	
                                              mcCursor.y = mcCursor.y - 2;
				break;
 
				case 39:
                                              // key right						
                                              mcCursor.x = mcCursor.x + 2;
				break;
 
				case 40:
					      // key down						
                                              mcCursor.y = mcCursor.y + 2;
				break;
			}
		}
 
		private function resetCursorPosition():void {
			mcCursor.x = MCCURSOR_X;
			mcCursor.y = MCCURSOR_Y;
		}
	}
}

package  
{
	import flash.display.MovieClip;
	/********************************************************************
	 * Description : This is the main document root file.
	 * @author Alex T.
	 ********************************************************************/
	public class Main extends MovieClip
	{
		public var mcPreloader : MovieClip;
		public var mcRSSContainer:MovieClip;
 
		public function Main() 
		{
			trace("init!") ;
			mcPreloader.visible = true;
			// Since, mcRSSContainer is the stage object of the class, 
			// we attach the listener here.This behaviour is similar to a doctor 
			// placing a stethoscope on your body to listen for heartbeat.
			// listening for the RSSReady customEvent to be dispatch.
			mcRSSContainer.addEventListener("RSSReady", handleRSSReady);
		}
 
		private function handleRSSReady(event):void {
			mcPreloader.visible = false;
		}
	}
}

package com.isgoodstuff 
{
	import fl.controls.List;
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.net.FileReferenceList;
	import flash.net.URLLoader;
	import flash.net.URLRequest;
	/********************************************************************
	* Description : This is mcRSSContainer Class. 
	* Contains a ListBox component. This class will load RSS using 
	* a URLLoader and then once loaded, sends a customEvent  or 
	* (dispatchEvent) which the Main is listening to, in order to hide 
	* mcPreloader.
	* @author Alex T.
	********************************************************************/
	public class mcRSSContainer extends MovieClip
	{
		public var listBox:List;
		public var rssLoader:URLLoader = new URLLoader();
		public var rssXML:XML = new XML();
		public function mcRSSContainer() 
		{
			trace("mcRSSContainer successfully initiatialize");
			startLoadingRSS();
		}
 
		private function startLoadingRSS():void {
			var rssURL:URLRequest =  new URLRequest("http://rss.cnn.com/rss/edition.rss");
			rssLoader.addEventListener(Event.COMPLETE, rssLoaded);
			rssLoader.load(rssURL);
		}
 
		private function rssLoaded(event):void {
			rssXML.ignoreWhitespace = true;
			rssXML = XML(rssLoader.data);
			for(var item:String in rssXML.channel.item) {
				listBox.addItem( {label: rssXML.channel.item[item].title } );
			}
			// This means the class has done all the RSS loading. Now we need to send a custom
			// Event (dispatchEvent) like a shout to other classes listening that data is ready.
			// The string RSSReady can be any other custom Event name you wanted. Just
			// Make sure when attaching listener has to "listen For" the particular string event.
			// Now see the mcRSSContainer.addEventListener("RSSReady", handleRSSReady); 
			// under Main.as
			dispatchEvent( new Event("RSSReady") );
		}
	}
 
}

package  
{
	import flash.display.MovieClip;
	import flash.events.Event;
	// Every class that import GlobalStatic can share the same method and 
	// singleton class, you dont need instantiate it. 
	// e.g. myGlobalStaticObject = new GlobalStatic();
	// We just use it's name like GlobalStatic.methodName( );
	import com.isgoodstuff.GlobalStatic;
	import flash.text.TextField;
 
	/************************************************************
	 * Description : This is the main actionscript file.
	 * @author Alex T.
	 ***********************************************************/
	public class Main extends MovieClip
	{
		// Note : In this demo, mcGlobalStatic is just a visual representation of the GlobalStatic
		// as everything is stored in memory.
		public var txtBlueScore:TextField;
		public var txtRedScore:TextField;
 
		public function Main() 
		{
			//Resets when the Main starts initializing
			txtRedScore.text = "0";
			txtBlueScore.text = "0";
			// Run all the time, to update the Main's fla txtBlueScore and txtRedScore
			// from GlobalStatic
			this.addEventListener(Event.ENTER_FRAME, handleUpdateScores);
		}
 
		private function handleUpdateScores(event):void {
			txtBlueScore.text = GlobalStatic.blueScore;
			txtRedScore.text = GlobalStatic.redScore;
		}
 
	}
 
}

package com.isgoodstuff 
{
	import flash.display.MovieClip;
	import flash.text.TextField;
 
	/****************************************************************************
	 * Description : This is the mcGlobalStatic / Singleton Class 
	 * actionscript file. Is a good practice to place all your other class 
	 * files inside a sub folders, com means common libraries folder
	 * isgoodstuff can be the company or organization. 
	 * @author Alex T.
	 ***************************************************************************/
	public class GlobalStatic extends MovieClip
	{
		private static var _iRedScore:int = 0;
		private static var _iBlueScore:int = 0;
 
		public function GlobalStatic() 
		{
			// Very useful to cross reference and sending data across classes.
			// See how mcRed and mcBlue get data from each other using
			// globalStatic
			trace("Initializing globalStatic / Singleton Class");
			_iRedScore = 0;
			_iBlueScore = 0;
		}
 
		// This is how to make a setter. So that other class can just use 
		// GlobalStatic.redScore = value; to assign latest redScore
		public static function set redScore(value:int) {
			_iRedScore = value;
		}
 
		// This is how to make a getter. So that other class can just use 
		// var myRedScore =  GlobalStatic.redScore to get latest redScore
		public static function get redScore() {
			return _iRedScore;
		}
 
		// This is how to make a setter. So that other class can just use 
		// GlobalStatic.blueScore = value; to assign latest blueScore
		public static function set blueScore(value:int) {
			_iBlueScore = value;
		}
 
		// This is how to make a getter. So that other class can just use 
		// var myBlueScore = GlobalStatic.blueScore to get latest blueScore
		public static function get blueScore() {
			return _iBlueScore;
		}
 
	}
 
}

package com.isgoodstuff 
{
	import flash.display.MovieClip;
	import flash.events.MouseEvent;
	import flash.text.TextField;
        // To get and receive value from GlobalStatic, we must first include it into our import
	import com.isgoodstuff.GlobalStatic;
 
	/************************************************************
	 * Description : This is the mcRed Class actionscript file.
	 * It is binded to the movieClip in Library named mcRed.
	 * @author Alex T.
	 ***********************************************************/
	public class mcRed extends MovieClip
	{
		// Instance placed in stage must be declared public var before
		// they can be used.
		public var txtRedScore : TextField;
		public var txtBlueScore : TextField;
		public var btnSet:MovieClip;
		public var btnGet:MovieClip;
 
		public function mcRed() 
		{
			//Reseting own numbers in own textfield.
			txtBlueScore.text = "0";
			txtRedScore.text = "0";
			btnGet.addEventListener(MouseEvent.CLICK, handleGetClick );
			btnSet.addEventListener(MouseEvent.CLICK, handleSetClick ) ;
		}
 
		private function handleGetClick(event) :void {
			txtBlueScore.text = String(GlobalStatic.blueScore);
		}
 
		private function handleSetClick(event):void {
			GlobalStatic.redScore = parseInt(txtRedScore.text);
		}
 
	}
 
}

package com.isgoodstuff 
{
	import flash.display.MovieClip;
	import flash.events.MouseEvent;
	import flash.text.TextField;
	// To get and receive value from GlobalStatic, we must first include it into our import
	import com.isgoodstuff.GlobalStatic;
 
	/************************************************************
	 * Description : This is the mcBlue Class actionscript file.
	 *It is binded to the movieClip in Library named mcBlue.
	 * @author Alex T.
	 ***********************************************************/
	public class mcBlue extends MovieClip
	{
		// Instance placed in stage must be declared public var before
		// they can be used.
		public var txtRedScore : TextField;
		public var txtBlueScore : TextField;
		public var btnSet:MovieClip;
		public var btnGet:MovieClip;
 
		public function mcBlue() 
		{
			//Reseting own numbers in own textfield.
			txtBlueScore.text = "0";
			txtRedScore.text = "0";
			btnGet.addEventListener(MouseEvent.CLICK, handleGetClick );
			btnSet.addEventListener(MouseEvent.CLICK, handleSetClick ) ;
		}
 
		private function handleGetClick(event) :void {
			txtRedScore.text = String(GlobalStatic.redScore);
		}
 
		private function handleSetClick(event):void {
			GlobalStatic.blueScore = parseInt(txtBlueScore.text);
		}
 
	}
 
}

package  
{
	// Importing all the class needed for the job.
        import flash.display.MovieClip;
	import flash.display.Loader;
	import flash.events.Event;
	import flash.net.URLRequest;
	/**
	 * Description : A Simple Class to Load External Images.
	 * URL : http://www.isgoodstuff.com
	 * @author Alex T.
	 **/
	public class Main extends MovieClip
	{
		public var mcPreloader:MovieClip;
		public var mcContainer:MovieClip;
		public var myImgLoader:Loader = new Loader();
 
		public function Main() 
		{
			// Inside the flas contains two onStage movieClip named mcPreloader and mcContainer.
			// Once the image is loaded, mcPreloader will disappear and mcContainer will be used
			// to contain the new image. (Jessica Alba's Pic)
			myImgLoader.load(new URLRequest("http://www.isgoodstuff.com/wp-content/uploads/2011/11/sample.png"));
			myImgLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, handleLoadCompleted);
		}
 
		private function handleLoadCompleted(evt:Event):void {
			mcPreloader.visible = false;
			// Once loaded, you can set it's height and width
			myImgLoader.width = 300;
			myImgLoader.height = 300;
			mcContainer.addChild( myImgLoader );
		}
 
	}
}